# Employee Stock Options

## Background

Putting a value on employee stock options (ESO) is a matter of some contention. Historically, many companies have granted copious options to their employees, without giving any true sense of their value in published accounts. Many companies would report significantly lower profits if option grants had to be included.

The Financial Accounting Standards Board (FASB) has recently set a standard in FASB 123 that the expense of ESO be included in a company's financial statements. If our politicians in Congress are any good, they will support them in this matter. Though FASB's standard allows for the use of the Black-Scholes formula, they also discuss (and now perhaps even favor) a better class of model. These are called binomial models in the FASB document.

### Intrinsic Value

Employee options nearly always have a strike K bigger than the current stock price S when they are granted. The value of the option lies in the fact that it is reasonably likely that at some later date, K>S.

A foolish measure of value, ignoring this likelihood, would be intrinsic value: i.e. MAX(0, S-K). In the past, even this simple approximation to the value was not required to appear in companies' financial statements, either as an expense in cashflow statements or as an obligation on the balance sheet.

### Black-Scholes Formula

There is a formula called the Black-Scholes formula used for pricing options that have just one allowable exercise date at the option tenor, and no other special features. That formula is quite inappropriate for pricing ESO, since ESO come with lots of other quirks, including vesting periods, stock holding periods, employee attrition, and (not least) lengthy time intervals in which they are exercisable at the employee's whim.

Someone using the Black-Scholes formula to price these options would be faced with many arbitrary decisions. For example, what correction factor should be used to capture the fact that some people depart every year, causing them to have to decide on immediate exercise? And, most important, what option tenor should go into the formula to capture the fact that the options may be exercised early should the stock price do well? Clearly the full option tenor is too much, but how little is too little?

The Black-Scholes formula is nonlinear, and hence unforgiving of approximations made to its inputs. Any so-called "correction factor" developed to try to adapt the formula to any early exercisable option, let alone ESO, is wholly arbitrary and ultimately unsupportable in myriad probable scenarios for the future path of the stock price.

### Black-Scholes Model

Instead, it is much saner to use the Black-Scholes model to price the options properly. The Black-Scholes formula is just one of the infinitely many solutions to the Black-Scholes model, and geared to a different kind of option than ESO. It makes far more sense to go back to the source, and use the model to price the option under the terms that have actually been granted.

To be fair, one could argue with justice that the Black-Scholes model itself is too simple: not particularly well suited to ESO due to their long maturities involved, and that some sort of more complicated stochastic volatility model is called for. Unfortunately, such models are a real pain to parameterize in a way everyone agrees on, so we stick with Black-Scholes.

## An Implementation Of a Model For Pricing ESO

I present here a reasonable algorithm for pricing ESO using the Black-Scholes model -- it's not a Leisen-Reimer tree but it works. Though I usually work in C, Python, or MatLab, I have implemented the algorithm in VBA, with the hope that it will prove more accessible to the world's accountants in this more common form. If you like, you can download an Excel spreadsheet already set up for pricing the options. Or you can download just the Visual Basic code, suitable for pasting into your own spreadsheet. Please pay attention to the license, which is GPL (free software).

For your browsing pleasure, I have also pasted the VB source code below.

### Overview of the option pricing algorithm

#### Assumptions and Features

I assume that stock prices follow geometric brownian motion, and that the issuer and employee will value the option as though the usual hedging arguments can apply. I ignore the discrete nature of dividend payouts, and assume they happen continuously at a rate proportional to the stock price.

I treat here options where the effect of holding and hedging restrictions, as well as other features detrimental to the employee, can be captured in a single discount which the employee will regard as (subjectively) applying to the stock price. Though the employee's perception will not affect the issuer's own valuation of the stock itself, it will reduce the option value through its effect on the employee's exercise decisions, which will appear suboptimal from the point of view of a disinterested party.

I do not treat reload (restoration) features. I assume that if an employee departs, he or she must decide immediately whether or not to exercise. Though I also do not explicitly treat blackout periods, it is worth noting that blackouts have very little effect on option value (at least within the Black-Scholes model framework).

#### Inputs

• The stock price starts out at a known value
• The options granted all have the same strike (in many cases it is the same as the stock price as of the grant date)
• The volatility of the stock price is a constant over the option's lifetime. The best way to set this volatility would be to infer it from the implied volatility of a market-quoted option of the same tenor. But if it must be historically calibrated, it should be calibrated to prices over the most recent stock history, throughout a period close to the option tenor.
• The risk-free interest rate
• The proportional rate at which the stock will pay out dividends over the tenor of the option.
• The option tenor
• The annual attrition rate at which employees depart the company, forced to make immediate exercise decisions
• The discount an employee will perceive as applying to the stock received from option exercise (due to holding periods, portfolio imbalance, lockouts, transaction costs, or irrationality)
• Times at which options vest, and what proportions vest at those times
• An acceptable complexity of the tree, represented by the number of timesteps.

#### Notes

• If you look at the code, you will see that it can be easily modified to report not just (A) the actual value of the option, but also (simultaneously) (B) the value of an option without a perceived discount, (C) the employee's subjective value for the option, and (D) the value of a european exercise option with the same attrition and discount features.
• For some reason, this VB does not appear to work with the OSX version of Microsoft Excel.
• Though I did not intend it as such, this code serves as an example to students of computational finance of how to do a trinomial tree in VB. As an example of such, it is somewhat crude. A more modern implementation if one were to use a tree might be based on Leisen-Reimer Trees.
• You can contact me at eso_at_boonstra_dot_o.rg. (with the obvious edits), or find me in the Chicago telephone book.

### Source code

```Option Explicit
Dim NotifyErrors As Boolean
Public Function ESO_BKB(stockPrice As Double, strike As Double, volatility As Double, interestRate As Double, _
dividendRate As Double, tenor As Double, valueDiscount As Double, attritionRate As Double, _
vestingTimes As Variant, vestingLevels As Variant, numSteps As Integer)
' Version 1.0
'(c) Copyright 2005, by Brian K. Boonstra, Ph.D.
'
'A function to price employee stock options.  This is similar to modeling
'   work I have done over the years as a quant for my various employers and
'   modeling examples I have taught to my classes at IIT Stuart Business School.
'
'   That means that you can freely use it, change it, and redistribute it so long
'   as any version you distribute has the source code freely available.  See below for
'   details. Other licensing terms are available -- I am in the Chicago phonebook, or
'   write to me at 1435 S. Federal St, Chicago, Illinois.
'
' Uses a tree to price employee stock options according to the following assumptions:
'   (1) Due to holding periods, portfolio constraints, or other reasons, an
'       employee receiving stock upon exercise will value it at less than the
'       market rate.  This undervaluation thus affects an employee's decision about
'       whether or not to exercise his/her options.  The valueDiscount represents
'       how much.  Typical valueDiscount: 3-5%
'   (2) Option-owning employees leave the company, forced to exercise or lose vested
'       stock options.  Stock options therefore go to term at a constant attrition
'       rate.  Note this is NOT the exactly the same as the employee attrition rate,
'       since (for example) senior employees holding 75% of the options might depart
'       at a rate of 10% per year, while junior employees might depart at a rate of
'       20% per year, yielding an option attrition rate of 12.5%.  Typical value: 5-20%
'   (3) When choosing to exercise, option holders do so according to a simple
'       probability of exercise formula that depends on the current time, the
'       option tenor, and perceived and actual exercise values. A function for this
'       is supplied in the code, but is easily changeable.
'   (4) Options come with a vesting schedule, ranging from nothing vested before
'       the first vesting time to fully vested at or before the option tenor.
'       Typical schedule (times in years): t={0,1,3}, level={0.33,0.67,1}
'   (5) The company stock price follows the Black-Scholes model.  The stock will
'       pay a constant dividend proportion per unit of stock, whatever the current
'       stock price.  The risk-free interest rate is a constant.  Stock price
'       volatility is also a constant.  In principle, volatility would best be
'       set by the price of an at-the-money over the counter call with a tenor
'       similar to that of the employee stock options in question.  However,
'       historical calibration (to a period roughly the same as the ESO tenor) may
'       be the only available means for illiquid names.
'       Typical values: S=50, strike=50, vol=50%, r=5%, dividendRate=2%
'   (6) The tree has enough timesteps in it to properly approximate a solution to
'       the model.  Try successively higher timestep counts to ensure you are
'       converging on the correct answer.  For example, you could try
'       10, 50, 100, 200, 500, 1000, 2000 timesteps and so on, to the limits
'       of your patience. Typical value: 50 * (tenor (in years)).

Dim perceived_df, perceived_stock_price, dt, root_half_dt, u, u_inv, _
mult_factor, riskfree_discount, attrition_prob, pu, pm, pd, _
carry_cost, current_time, current_stock_price, _
holder_early_exer_val, eex_value, accumulated_vesting, _
attr_cont_rate, drift_speed, issuer_option_value, _
holder_option_value, no_perception_option_value, european_option_value _
As Double
Dim bank_no_exer(), ignore_perception_no_exer(), holder_no_exer(), euro_no_exer(), _
issuer(), holder(), ignore_perception(), european(), _
issuer_new(), holder_new(), ignore_perception_new(), european_new(), _
weights(), stock_prices() _
As Double
Dim i, j, vest, num_vestings, step_num _
As Integer
Dim vested_one_or_zero() As Integer
Dim inputsOK As Boolean
Dim tree_probs As Variant
Dim prob_of_exer, prob_of_exer_attr, prob_of_exer_noperc, prob_of_exer_noperc_attr As Variant

NotifyErrors = True
inputsOK = ESO_CheckInputs(stockPrice, strike, volatility, interestRate, _
dividendRate, tenor, valueDiscount, attritionRate, _
vestingTimes, vestingLevels, numSteps)
If Not inputsOK Then
ESO_BKB = -1
Return
End If

num_vestings = VestingLength(vestingTimes)

' Discount factor yielding perceived value
perceived_df = 1 - valueDiscount

'Step sizes
dt = tenor / numSteps
root_half_dt = Math.Sqr(dt / 2#)
u = Exp(2# * volatility * root_half_dt)
u_inv = 1# / u

' Set array sizes.  We will have 2-d arrays for holding option values...one dimension captures
'   option value along a variety of stock prices (as normal for tree solutions to BS) whike
'   the other dimension captures values according to vesting cohorts
ReDim issuer(-numSteps - 1 To numSteps + 1, num_vestings)
ReDim issuer_new(-numSteps - 1 To numSteps + 1, num_vestings)

ReDim holder(-numSteps - 1 To numSteps + 1, num_vestings)
ReDim holder_new(-numSteps - 1 To numSteps + 1, num_vestings)

ReDim ignore_perception(-numSteps - 1 To numSteps + 1, num_vestings)
ReDim ignore_perception_new(-numSteps - 1 To numSteps + 1, num_vestings)

ReDim european(-numSteps - 1 To numSteps + 1, num_vestings)
ReDim european_new(-numSteps - 1 To numSteps + 1, num_vestings)

ReDim issuer_no_exer(num_vestings)
ReDim ignore_perception_no_exer(num_vestings)
ReDim holder_no_exer(num_vestings)
ReDim euro_no_exer(num_vestings)

ReDim vested_one_or_zero(num_vestings)
ReDim weights(num_vestings)

ReDim stock_prices(-numSteps - 1 To numSteps + 1)

' A multiplication factor captures the stock price at the current node
mult_factor = u ^ (numSteps + 2)

' Set up terminal values
For i = numSteps + 1 To -numSteps - 1 Step -1
' The multiplication factor for this grid point
mult_factor = mult_factor * u_inv

' Actual and perceived price of stock
stock_prices(i) = stockPrice * mult_factor
perceived_stock_price = perceived_df * stockPrice * mult_factor

' Loop over vestings, making final value assignments where appropriate
For vest = 1 To num_vestings
' Allow vesting to be after expiry, however odd
If vestingTimes(vest) < tenor Then
' Perceived option value, which affects exercise decisions
holder(i, vest) = perceived_stock_price - strike
If holder(i, vest) < 0# Then
' Option has no value if the stock is perceived to be underwater
issuer(i, vest) = 0#
holder(i, vest) = 0#
Else
' Holder wants to exercise, so the option has value equal to market value
issuer(i, vest) = stock_prices(i) - strike
End If
european(i, vest) = issuer(i, vest)

' We also track and could report prices that do not allow for perceived discounts
ignore_perception(i, vest) = stock_prices(i) - strike
If ignore_perception(i, vest) < 0# Then
ignore_perception(i, vest) = 0#
End If
End If
Next vest
Next i

' Per-period discount
riskfree_discount = Math.Exp(-interestRate * dt)

' Attrition probability per period, translated from an annual rate to a per-timestep
'   rate by assuming continuous attrition
attrition_prob = 1 - Math.Exp(Math.Log(1# - attritionRate) * dt)

' The carry cost is the drift of the stock under the risk-free measure
carry_cost = interestRate - dividendRate

' Probabilities on the tree
tree_probs = ESO_BKB_TreeProbs(u, dt, carry_cost, volatility)
pu = tree_probs(1)
pm = tree_probs(0)
pd = tree_probs(-1)

' We now approximate the PDE solution with a tree (or, if you like, an
'       explicit finite-difference scheme for the initial value problem in backwards time).
'
' There are several missing numerical efficiencies, such as finding (and not calculating
'   beyond) the exercise boundary, assignment of local constants to avoid array
'   references, extra calculations made for values we don't end up returning,
'   unpadding arrays, and multiplications we could cache in local variables
For step_num = numSteps To 1 Step -1
current_time = (step_num - 1) * dt

' Record which vesting cohorts have vested.   This loop could be made
'   more efficient, but is a small part of the algorithm cost
For vest = 1 To num_vestings
If vestingTimes(vest) <= current_time Then
vested_one_or_zero(vest) = 1
Else
vested_one_or_zero(vest) = 0
End If
Next vest

' Loop over stock prices
For i = step_num To -step_num Step -1
current_stock_price = stock_prices(i)

' Option holder's perception of value of the stock he/she would receive on exercise
perceived_stock_price = perceived_df * current_stock_price

' True early exercise value
eex_value = current_stock_price - strike
' Perceived early exercise value
holder_early_exer_val = perceived_stock_price - strike

' Loop over vestings, assigning option values of various types
For vest = 1 To num_vestings
' One more period of holding the american option, issuer's perspective
issuer_no_exer(vest) = riskfree_discount * (pu * issuer(i + 1, vest) + _
pm * issuer(i, vest) + pd * issuer(i - 1, vest))
' One more period of the option with no perceptin discount
ignore_perception_no_exer(vest) = riskfree_discount * (pu * ignore_perception(i + 1, vest) + _
pm * ignore_perception(i, vest) + pd * ignore_perception(i - 1, vest))
' One more period of holding the american option, holder's perspective
holder_no_exer(vest) = riskfree_discount * (pu * holder(i + 1, vest) + _
pm * holder(i, vest) + pd * holder(i - 1, vest))
' Get the value of holding the european option one more period
euro_no_exer(vest) = riskfree_discount * (pu * european(i + 1, vest) + _
pm * european(i, vest) + pd * european(i - 1, vest))
Next vest

' Exercise probabilities by vesting cohort(which will of course be zero for unvested options)
prob_of_exer = ESO_Exercise_Function(holder_early_exer_val, holder_no_exer, vested_one_or_zero, current_time, tenor)

' The same, but now the holder is leaving and must decide immediately
prob_of_exer_attr = ESO_Exercise_Function(holder_early_exer_val, 0, vested_one_or_zero, current_time, current_time)

' Other exercise probabilities (no perception discount)
prob_of_exer_noperc = ESO_Exercise_Function(eex_value, ignore_perception_no_exer, vested_one_or_zero, current_time, tenor)
prob_of_exer_noperc_attr = ESO_Exercise_Function(eex_value, 0, vested_one_or_zero, current_time, current_time)

' Backwarddate on the tree to get new option values
For vest = 1 To num_vestings
issuer_new(i, vest) = attrition_prob * prob_of_exer_attr(vest) * vested_one_or_zero(vest) * eex_value + _
(1 - attrition_prob) * (vested_one_or_zero(vest) * (prob_of_exer(vest) * eex_value + (1 - prob_of_exer(vest)) * issuer_no_exer(vest)) + _
(1 - vested_one_or_zero(vest)) * issuer_no_exer(vest))
ignore_perception_new(i, vest) = attrition_prob * prob_of_exer_noperc_attr(vest) * vested_one_or_zero(vest) * eex_value + _
(1 - attrition_prob) * (vested_one_or_zero(vest) * (prob_of_exer_noperc(vest) * eex_value + (1 - prob_of_exer_noperc(vest)) * ignore_perception_no_exer(vest)) + _
(1 - vested_one_or_zero(vest)) * ignore_perception_no_exer(vest))
holder_new(i, vest) = attrition_prob * prob_of_exer_attr(vest) * vested_one_or_zero(vest) * holder_early_exer_val + _
(1 - attrition_prob) * (vested_one_or_zero(vest) * (prob_of_exer(vest) * holder_early_exer_val + (1 - prob_of_exer(vest)) * holder_no_exer(vest)) + _
(1 - vested_one_or_zero(vest)) * holder_no_exer(vest))
european_new(i, vest) = attrition_prob * prob_of_exer_attr(vest) * vested_one_or_zero(vest) * eex_value + _
(1 - attrition_prob) * euro_no_exer(vest)
Next vest

Next i ' End loop over stock prices

' Update the values in our vectors
issuer = issuer_new
ignore_perception = ignore_perception_new
holder = holder_new
european = european_new

Next step_num

' Now figure out average values by weighting according to vesting cohorts
accumulated_vesting = 0
For vest = 1 To num_vestings
weights(vest) = vestingLevels(vest) - accumulated_vesting
accumulated_vesting = vestingLevels(vest)
Next vest

issuer_option_value = 0#
holder_option_value = 0#
no_perception_option_value = 0#
european_option_value = 0#
For vest = 1 To num_vestings
issuer_option_value = issuer_option_value + issuer(0, vest) * weights(vest)
holder_option_value = holder(0, vest) * weights(vest)
no_perception_option_value = ignore_perception(0, vest) * weights(vest)
european_option_value = european(0, vest) * weights(vest)
Next vest

ESO_BKB = issuer_option_value

End Function

Public Function ESO_Exercise_Function(ByVal exerciseValue As Double, noExerciseValue As Variant, vested As Variant, ByVal nowTime As Double, ByVal tenor As Double) As Double()
Dim vest As Integer
Dim prob() As Double
Dim noExer As Double

ReDim prob(LBound(vested) To UBound(vested))

For vest = LBound(vested) To UBound(vested)
prob(vest) = 0#
If 1 = vested(vest) Then
If IsArray(noExerciseValue) Then
noExer = noExerciseValue(vest)
Else
noExer = noExerciseValue
End If
If exerciseValue > noExer Then
prob(vest) = 1#
End If
End If
Next vest

ESO_Exercise_Function = prob

End Function
Public Function ESO_BKB_TreeProbs(ByVal u As Double, ByVal dt As Double, ByVal carry_cost As Double, ByVal volatility As Double) As Variant
Dim p(-1 To 1) As Double
Dim i As Integer
Dim drift, vardrift As Double

drift = Math.Exp(carry_cost * dt)
vardrift = Math.Exp(dt * (2# * carry_cost + volatility * volatility))

p(1) = (1 - drift * (u + 1) + u * vardrift) / ((u - 1) ^ 2 * (u + 1))
p(0) = (drift * (u ^ 2 + 1) - u * (vardrift + 1)) / ((u - 1) ^ 2)
p(-1) = 1# - p(1) - p(0)

If p(1) < 0 Or p(0) < 0 Or p(-1) < 0 Then
If NotifyErrors Then
MsgBox ("Negative tree probabilities encountered.  Try more timesteps.")
End If
For i = -1 To 1
p(i) = 0
Next i
End If

ESO_BKB_TreeProbs = p

End Function
Public Function ESO_CheckInputs(stockPrice As Double, strike As Double, volatility As Double, interestRate As Double, _
dividendRate As Double, tenor As Double, valueDiscount As Double, attritionRate As Double, _
vestingTimes As Variant, vestingLevels As Variant, numSteps As Integer) As Boolean

Dim numVestings, numVestingTimes As Integer
Dim errorMsg As String
Dim inputType As String
Dim i As Integer
Dim v, vold, t, told As Double

If numSteps < 1 Then
If NotifyErrors Then
MsgBox ("Step count must be at least 1")
End If
ESO_CheckInputs = False
Return
End If

If stockPrice <= 0 Then
If NotifyErrors Then
MsgBox ("Stock price must be greater than zero")
End If
ESO_CheckInputs = False
Return
End If

If strike <= 0 Then
If NotifyErrors Then
MsgBox ("Strike price must be greater than zero")
End If
ESO_CheckInputs = False
Return
End If

If volatility <= 0 Then
If NotifyErrors Then
MsgBox ("Volatility must be greater than zero")
End If
ESO_CheckInputs = False
Return
End If

If interestRate <= 0 Then
If NotifyErrors Then
MsgBox ("Risk-free interest rate must be greater than zero")
End If
ESO_CheckInputs = False
Return
End If

If tenor <= 0 Then
If NotifyErrors Then
MsgBox ("Option tenor must be greater than zero")
End If
ESO_CheckInputs = False
Return
End If

If valueDiscount < 0 Then
If NotifyErrors Then
MsgBox ("The value discount cannot be less than zero...it must be between 0 and 1 (0% and 100%)")
End If
ESO_CheckInputs = False
Return
End If

If valueDiscount > 1 Then
If NotifyErrors Then
MsgBox ("The value discount cannot be more than 1.0...it must be between 0 and 1 (0% and 100%)")
End If
ESO_CheckInputs = False
Return
End If

If attritionRate < 0 Then
If NotifyErrors Then
MsgBox ("The attrition rate cannot be less than zero...it must be at least 0 and less than 1")
End If
ESO_CheckInputs = False
Return
End If

If attritionRate >= 1 Then
If NotifyErrors Then
MsgBox ("The attrition rate cannot be 1.0 or greater...it must be at least 0 and less than 1")
End If
ESO_CheckInputs = False
Return
End If

numVestingTimes = VestingLength(vestingTimes)
numVestings = VestingLength(vestingLevels)

If numVestingTimes <= 0 Then
If NotifyErrors Then
errorMsg = "The number of vesting times (" & numVestingTimes & ") must be more than zero"
MsgBox (errorMsg)
End If
ESO_CheckInputs = False
Return
End If

If numVestings <> numVestingTimes Then
If NotifyErrors Then
errorMsg = "The number of vesting times (" & numVestingTimes & ") must be equal the number of vesting levels (" & numVestings & ")"
MsgBox (errorMsg)
End If
ESO_CheckInputs = False
Return
End If

vold = 0
told = vestingTimes(1) - 0.1
For i = 1 To numVestings
v = vestingLevels(i)
t = vestingTimes(i)
If v < 0 Then
If NotifyErrors Then
errorMsg = "The vesting level (" & v & ") at index " & i & " was negative"
MsgBox (errorMsg)
End If
ESO_CheckInputs = False
Return
ElseIf v > 1 Then
If NotifyErrors Then
errorMsg = "The vesting level (" & v & ") at index " & i & " was greater than 1"
MsgBox (errorMsg)
End If
ESO_CheckInputs = False
Return
End If
If v < vold Then
If NotifyErrors Then
errorMsg = "The vesting level (" & v & ") at index " & i & " was less than the previous level of " & vold
MsgBox (errorMsg)
End If
ESO_CheckInputs = False
Return
End If
If t <= told Then
If NotifyErrors Then
errorMsg = "The vesting time (" & t & ") at index " & i & " was less than or equal to the previous time of " & told
MsgBox (errorMsg)
End If
ESO_CheckInputs = False
Return
End If
vold = v
told = t
Next i

ESO_CheckInputs = True

End Function
Public Function VestingLength(vestingvar As Variant) As Integer
Dim inputType As String

If "Range" = TypeName(vestingvar) Then
VestingLength = vestingvar.Count
ElseIf IsArray(vestingvar) Then
VestingLength = 1 + UBound(vestingvar) - LBound(vestingvar)
Else
VestingLength = -1
End If
End Function

'              Version 2, June 1991
'
'  Copyright (C) 1989, 1991 Free Software Foundation, Inc.
'                        59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
'  Everyone is permitted to copy and distribute verbatim copies
'  of this license document, but changing it is not allowed.
'
'               Preamble
'
'   The licenses for most software are designed to take away your
' freedom to share and change it.  By contrast, the GNU General Public
' License is intended to guarantee your freedom to share and change free
' software--to make sure the software is free for all its users.  This
' General Public License applies to most of the Free Software
' Foundation's software and to any other program whose authors commit to
' using it.  (Some other Free Software Foundation software is covered by
' the GNU Library General Public License instead.)  You can apply it to
'
'   When we speak of free software, we are referring to freedom, not
' price.  Our General Public Licenses are designed to make sure that you
' have the freedom to distribute copies of free software (and charge for
' this service if you wish), that you receive source code or can get it
' if you want it, that you can change the software or use pieces of it
' in new free programs; and that you know you can do these things.
'
'   To protect your rights, we need to make restrictions that forbid
' anyone to deny you these rights or to ask you to surrender the rights.
' These restrictions translate to certain responsibilities for you if you
' distribute copies of the software, or if you modify it.
'
'   For example, if you distribute copies of such a program, whether
' gratis or for a fee, you must give the recipients all the rights that
' you have.  You must make sure that they, too, receive or can get the
' source code.  And you must show them these terms so they know their
' rights.
'
'   We protect your rights with two steps: (1) copyright the software, and
' (2) offer you this license which gives you legal permission to copy,
' distribute and/or modify the software.
'
'   Also, for each author's protection and ours, we want to make certain
' that everyone understands that there is no warranty for this free
' software.  If the software is modified by someone else and passed on, we
' want its recipients to know that what they have is not the original, so
' that any problems introduced by others will not reflect on the original
' authors' reputations.
'
'   Finally, any free program is threatened constantly by software
' patents.  We wish to avoid the danger that redistributors of a free
' program will individually obtain patent licenses, in effect making the
' program proprietary.  To prevent this, we have made it clear that any
' patent must be licensed for everyone's free use or not licensed at all.
'
'   The precise terms and conditions for copying, distribution and
' modification follow.
'
'    TERMS AND CONDITIONS FOR COPYING, DISTRIBUTION AND MODIFICATION
'
'   0. This License applies to any program or other work which contains
' a notice placed by the copyright holder saying it may be distributed
' under the terms of this General Public License.  The "Program", below,
' refers to any such program or work, and a "work based on the Program"
' means either the Program or any derivative work under copyright law:
' that is to say, a work containing the Program or a portion of it,
' either verbatim or with modifications and/or translated into another
' language.  (Hereinafter, translation is included without limitation in
'
' Activities other than copying, distribution and modification are not
' covered by this License; they are outside its scope.  The act of
' running the Program is not restricted, and the output from the Program
' is covered only if its contents constitute a work based on the
' Program (independent of having been made by running the Program).
' Whether that is true depends on what the Program does.
'
'   1. You may copy and distribute verbatim copies of the Program's
' source code as you receive it, in any medium, provided that you
' conspicuously and appropriately publish on each copy an appropriate
' copyright notice and disclaimer of warranty; keep intact all the
' notices that refer to this License and to the absence of any warranty;
' and give any other recipients of the Program a copy of this License
' along with the Program.
'
' You may charge a fee for the physical act of transferring a copy, and
' you may at your option offer warranty protection in exchange for a fee.
'
'   2. You may modify your copy or copies of the Program or any portion
' of it, thus forming a work based on the Program, and copy and
' distribute such modifications or work under the terms of Section 1
' above, provided that you also meet all of these conditions:
'
'     a) You must cause the modified files to carry prominent notices
'     stating that you changed the files and the date of any change.
'
'     b) You must cause any work that you distribute or publish, that in
'     whole or in part contains or is derived from the Program or any
'     part thereof, to be licensed as a whole at no charge to all third
'     parties under the terms of this License.
'
'     c) If the modified program normally reads commands interactively
'     when run, you must cause it, when started running for such
'     interactive use in the most ordinary way, to print or display an
'     announcement including an appropriate copyright notice and a
'     notice that there is no warranty (or else, saying that you provide
'     a warranty) and that users may redistribute the program under
'     these conditions, and telling the user how to view a copy of this
'     License.  (Exception: if the Program itself is interactive but
'     does not normally print such an announcement, your work based on
'     the Program is not required to print an announcement.)
'
' These requirements apply to the modified work as a whole.  If
' identifiable sections of that work are not derived from the Program,
' and can be reasonably considered independent and separate works in
' themselves, then this License, and its terms, do not apply to those
' sections when you distribute them as separate works.  But when you
' distribute the same sections as part of a whole which is a work based
' on the Program, the distribution of the whole must be on the terms of
' entire whole, and thus to each and every part regardless of who wrote it.
'
' Thus, it is not the intent of this section to claim rights or contest
' your rights to work written entirely by you; rather, the intent is to
' exercise the right to control the distribution of derivative or
' collective works based on the Program.
'
' In addition, mere aggregation of another work not based on the Program
' with the Program (or with a work based on the Program) on a volume of
' a storage or distribution medium does not bring the other work under
' the scope of this License.
'
'   3. You may copy and distribute the Program (or a work based on it,
' under Section 2) in object code or executable form under the terms of
' Sections 1 and 2 above provided that you also do one of the following:
'
'     a) Accompany it with the complete corresponding machine-readable
'     source code, which must be distributed under the terms of Sections
'     1 and 2 above on a medium customarily used for software interchange; or,
'
'     b) Accompany it with a written offer, valid for at least three
'     years, to give any third party, for a charge no more than your
'     cost of physically performing source distribution, a complete
'     machine-readable copy of the corresponding source code, to be
'     distributed under the terms of Sections 1 and 2 above on a medium
'     customarily used for software interchange; or,
'
'     c) Accompany it with the information you received as to the offer
'     to distribute corresponding source code.  (This alternative is
'     allowed only for noncommercial distribution and only if you
'     received the program in object code or executable form with such
'     an offer, in accord with Subsection b above.)
'
' The source code for a work means the preferred form of the work for
' making modifications to it.  For an executable work, complete source
' code means all the source code for all modules it contains, plus any
' associated interface definition files, plus the scripts used to
' control compilation and installation of the executable.  However, as a
' special exception, the source code distributed need not include
' anything that is normally distributed (in either source or binary
' form) with the major components (compiler, kernel, and so on) of the
' operating system on which the executable runs, unless that component
' itself accompanies the executable.
'
' If distribution of executable or object code is made by offering
' access to copy the source code from the same place counts as
' distribution of the source code, even though third parties are not
' compelled to copy the source along with the object code.
'
'   4. You may not copy, modify, sublicense, or distribute the Program
' except as expressly provided under this License.  Any attempt
' otherwise to copy, modify, sublicense or distribute the Program is
' However, parties who have received copies, or rights, from you under
' this License will not have their licenses terminated so long as such
' parties remain in full compliance.
'
'   5. You are not required to accept this License, since you have not
' signed it.  However, nothing else grants you permission to modify or
' distribute the Program or its derivative works.  These actions are
' prohibited by law if you do not accept this License.  Therefore, by
' modifying or distributing the Program (or any work based on the
' Program), you indicate your acceptance of this License to do so, and
' all its terms and conditions for copying, distributing or modifying
' the Program or works based on it.
'
'   6. Each time you redistribute the Program (or any work based on the
' original licensor to copy, distribute or modify the Program subject to
' these terms and conditions.  You may not impose any further
' restrictions on the recipients' exercise of the rights granted herein.
' You are not responsible for enforcing compliance by third parties to
'
'   7. If, as a consequence of a court judgment or allegation of patent
' infringement or for any other reason (not limited to patent issues),
' conditions are imposed on you (whether by court order, agreement or
' otherwise) that contradict the conditions of this License, they do not
' excuse you from the conditions of this License.  If you cannot
' distribute so as to satisfy simultaneously your obligations under this
' License and any other pertinent obligations, then as a consequence you
' may not distribute the Program at all.  For example, if a patent
' license would not permit royalty-free redistribution of the Program by
' all those who receive copies directly or indirectly through you, then
' the only way you could satisfy both it and this License would be to
' refrain entirely from distribution of the Program.
'
' If any portion of this section is held invalid or unenforceable under
' any particular circumstance, the balance of the section is intended to
' apply and the section as a whole is intended to apply in other
' circumstances.
'
' It is not the purpose of this section to induce you to infringe any
' patents or other property right claims or to contest validity of any
' such claims; this section has the sole purpose of protecting the
' integrity of the free software distribution system, which is
' generous contributions to the wide range of software distributed
' through that system in reliance on consistent application of that
' system; it is up to the author/donor to decide if he or she is willing
' to distribute software through any other system and a licensee cannot
' impose that choice.
'
' This section is intended to make thoroughly clear what is believed to
' be a consequence of the rest of this License.
'
'   8. If the distribution and/or use of the Program is restricted in
' certain countries either by patents or by copyrighted interfaces, the
' may add an explicit geographical distribution limitation excluding
' those countries, so that distribution is permitted only in or among
' countries not thus excluded.  In such case, this License incorporates
' the limitation as if written in the body of this License.
'
'   9. The Free Software Foundation may publish revised and/or new versions
' of the General Public License from time to time.  Such new versions will
' be similar in spirit to the present version, but may differ in detail to
' address new problems or concerns.
'
' Each version is given a distinguishing version number.  If the Program
' specifies a version number of this License which applies to it and "any
' later version", you have the option of following the terms and conditions
' either of that version or of any later version published by the Free
' Software Foundation.  If the Program does not specify a version number of
' Foundation.
'
'   10. If you wish to incorporate parts of the Program into other free
' programs whose distribution conditions are different, write to the author
' to ask for permission.  For software which is copyrighted by the Free
' Software Foundation, write to the Free Software Foundation; we sometimes
' make exceptions for this.  Our decision will be guided by the two goals
' of preserving the free status of all derivatives of our free software and
' of promoting the sharing and reuse of software generally.
'
'               NO WARRANTY
'
'   11. BECAUSE THE PROGRAM IS LICENSED FREE OF CHARGE, THERE IS NO WARRANTY
' FOR THE PROGRAM, TO THE EXTENT PERMITTED BY APPLICABLE LAW.  EXCEPT WHEN
' OTHERWISE STATED IN WRITING THE COPYRIGHT HOLDERS AND/OR OTHER PARTIES
' PROVIDE THE PROGRAM "AS IS" WITHOUT WARRANTY OF ANY KIND, EITHER EXPRESSED
' OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
' MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.  THE ENTIRE RISK AS
' TO THE QUALITY AND PERFORMANCE OF THE PROGRAM IS WITH YOU.  SHOULD THE
' PROGRAM PROVE DEFECTIVE, YOU ASSUME THE COST OF ALL NECESSARY SERVICING,
' REPAIR OR CORRECTION.
'
'   12. IN NO EVENT UNLESS REQUIRED BY APPLICABLE LAW OR AGREED TO IN WRITING
' WILL ANY COPYRIGHT HOLDER, OR ANY OTHER PARTY WHO MAY MODIFY AND/OR
' REDISTRIBUTE THE PROGRAM AS PERMITTED ABOVE, BE LIABLE TO YOU FOR DAMAGES,
' INCLUDING ANY GENERAL, SPECIAL, INCIDENTAL OR CONSEQUENTIAL DAMAGES ARISING
' OUT OF THE USE OR INABILITY TO USE THE PROGRAM (INCLUDING BUT NOT LIMITED
' TO LOSS OF DATA OR DATA BEING RENDERED INACCURATE OR LOSSES SUSTAINED BY
' YOU OR THIRD PARTIES OR A FAILURE OF THE PROGRAM TO OPERATE WITH ANY OTHER
' PROGRAMS), EVEN IF SUCH HOLDER OR OTHER PARTY HAS BEEN ADVISED OF THE
' POSSIBILITY OF SUCH DAMAGES.
'
'            END OF TERMS AND CONDITIONS
'
'       How to Apply These Terms to Your New Programs
'
'   If you develop a new program, and you want it to be of the greatest
' possible use to the public, the best way to achieve this is to make it
' free software which everyone can redistribute and change under these terms.
'
'   To do so, attach the following notices to the program.  It is safest
' to attach them to the start of each source file to most effectively
' convey the exclusion of warranty; and each file should have at least
' the "copyright" line and a pointer to where the full notice is found.
'
'     <one line to give the program's name and a brief idea of what it does.>
'     Copyright (C) <year>  <name of author>
'
'     This program is free software; you can redistribute it and/or modify
'     the Free Software Foundation; either version 2 of the License, or
'     (at your option) any later version.
'
'     This program is distributed in the hope that it will be useful,
'     but WITHOUT ANY WARRANTY; without even the implied warranty of
'     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
'     GNU General Public License for more details.
'
'     You should have received a copy of the GNU General Public License
'     along with this program; if not, write to the Free Software
'     Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
'
'
' Also add information on how to contact you by electronic and paper mail.
'
' If the program is interactive, make it output a short notice like this
' when it starts in an interactive mode:
'
'     Gnomovision version 69, Copyright (C) year name of author
'     Gnomovision comes with ABSOLUTELY NO WARRANTY; for details type `show w'.
'     This is free software, and you are welcome to redistribute it
'     under certain conditions; type `show c' for details.
'
' The hypothetical commands `show w' and `show c' should show the appropriate
' parts of the General Public License.  Of course, the commands you use may
' be called something other than `show w' and `show c'; they could even be
'
' You should also get your employer (if you work as a programmer) or your
' school, if any, to sign a "copyright disclaimer" for the program, if
' necessary.  Here is a sample; alter the names:
'
'   Yoyodyne, Inc., hereby disclaims all copyright interest in the program
'   `Gnomovision' (which makes passes at compilers) written by James Hacker.
'
'   <signature of Ty Coon>, 1 April 1989
'   Ty Coon, President of Vice
'
' This General Public License does not permit incorporating your program into
' proprietary programs.  If your program is a subroutine library, you may
' consider it more useful to permit linking proprietary applications with the
' library.  If this is what you want to do, use the GNU Library General